XL Fortran for AIX 8.1

Language Reference

Lines and Source Formats

A line is a horizontal arrangement of characters. By contrast, a column is a vertical arrangement of characters, where each character, or each byte of a multibyte character, in a given column shares the same line position.

+-------------------------------IBM Extension--------------------------------+

Because XL Fortran measures lines in bytes, these definitions apply only to lines containing single-byte characters. Each byte of a multibyte character occupies one column.

+----------------------------End of IBM Extension----------------------------+

The kinds of lines are:

Initial Line	Is the first line of a statement.
Continuation Line	Continues a statement beyond its initial line.
Comment Line	Does not affect the executable program and can be used for documentation. The comment text continues to the end of a line. Although comment lines can follow one another, a comment line cannot be continued. A line of all white space or a zero-length line is a comment line without any text. Comment text can contain any characters allowed in a character context. If an initial line or continuation line is not continued, or if it is continued but not in a character context, an inline comment can be placed on the same line, to the right of any statement label, statement text, and continuation character that may be present. An exclamation mark (!) begins an inline comment.
* Conditional Compilation Line	Indicates that the line should only be compiled if recognition of conditional compilation lines is enabled. A conditional compilation sentinel should appear on a conditional compilation line. (See Conditional Compilation) *
* Debug Line	Indicates that the line is for debugging code (for fixed source form only). In XL Fortran the letter `D` or `X` must be specified in column 1. (See Debug Lines) *
* Directive Line	Provides instructions or information to the compiler in XL Fortran (see Chapter 11, Directives). *

+-------------------------------IBM Extension--------------------------------+

Note:: * Debug Line and DirectiveLine are used in XL Fortran

In XL Fortran, source lines can be in fixed source form or free source form format. Use the SOURCEFORM directive to mix source formats within the same program unit. Fixed source form is the default when using the f77, fort77, xlf, xlf_r or xlf_r7 invocation commands. Fortran 90 free source form is the default when using the xlf90, xlf90_r, xlf90_r7, xlf95, xlf95_r or xlf95_r7 invocation commands.

See "Compiling an XL Fortran Program" in the User's Guide for details on invocation commands.

+----------------------------End of IBM Extension----------------------------+

Fixed Source Form

+-------------------------------IBM Extension--------------------------------+

A fixed source form line is a sequence of 1 to 132 characters. The default line size (as stipulated in Fortran 95) is 72 characters, but can be changed in XL Fortran by using the -qfixed=right_margin compiler option (see the User's Guide).

+----------------------------End of IBM Extension----------------------------+

Columns beyond the right margin are not part of the line and can be used for identification, sequencing, or any other purpose.

Except within a character context, white space is insignificant; that is, you can imbed white space between and within lexical tokens, without affecting the way the compiler will treat them.

+-------------------------------IBM Extension--------------------------------+

Tab formatting means there is a tab character in columns 1 through 6 of an initial line in XL Fortran, which directs the compiler to interpret the next character as being in column 7.

+----------------------------End of IBM Extension----------------------------+

Requirements for lines and for items on those lines are:

A comment line begins with a C, c, or an asterisk (*) in column 1, or is all white space. Comments can also follow an exclamation mark (!), except when the exclamation mark is in column 6 or in a character context.
For an initial line without tab formatting:
- Columns 1 through 5 contain either blanks, a statement label, a D or an X in column 1 optionally followed by a statement label.
- Column 6 contains a blank or zero.
- Columns 7 through to the right margin contain statement text, possibly followed by other statements or by an inline comment.
```
+-------------------------------IBM Extension--------------------------------+
```
For an initial line with tab formatting in XL Fortran:
- Columns 1 through 6 begin with either blanks, a statement label, a D or an X in column 1, optionally followed by a statement label. This must be followed by a tab character.
- If the -qxflag=oldtab compiler option is specified, all columns from the column immediately following the tab character through to the right margin contain statement text, possibly followed by other statements and by an inline comment.
- If the -qxflag=oldtab compiler option is not specified, all columns from column 7 (which corresponds to the character after the tab) to the right margin contain statement text, possibly followed by other statements and by an inline comment.
```
+----------------------------End of IBM Extension----------------------------+
```
For a continuation line:
- Column 1 must not contain C, c, or an asterisk. Columns 1 through 5 must not contain an exclamation mark as the leftmost nonblank character.
```
+-------------------------------IBM Extension--------------------------------+
```
  Column 1 can contain a D (signifying a debug line) in XL Fortran. Otherwise, these columns can contain any characters allowed in a character context; these characters are ignored.
```
+----------------------------End of IBM Extension----------------------------+
```
- Column 6 must have either a nonzero character or a nonwhite space character. The character in column 6 is referred to as the continuation character. Exclamation marks and semicolons are valid continuation characters.
- Columns 7 through to the right margin contain continued statement text, possibly followed by other statements and an inline comment.
- Neither the END statement nor a statement whose initial line appears to be a program unit END statement can be continued.
```
+-------------------------------IBM Extension--------------------------------+
```
- There is no limit to the number of continuation lines for a statement in XL Fortran, but a statement cannot be longer than 6700 characters.
```
+----------------------------End of IBM Extension----------------------------+
```
The Fortran standards limit the number of continuation lines to 19.

A semicolon (;) separates statements on a single source line, except when it appears in a character context, in a comment, or in columns 1 through 6. Two or more semicolon separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Statements following a semicolon on the same line cannot be labeled. Additional statements cannot follow a program unit END statement on the same line.

Debug Lines

+-------------------------------IBM Extension--------------------------------+

A debug line, allowed only for fixed source form, contains source code used for debugging and is specified in XL Fortran by the letter D, or the letter X in column 1. The handling of debug lines depends on the -qdlines or the -qxlines compiler options:

If you specify the -qdlines option, the compiler interprets the D in column 1 as a blank, and handles such lines as lines of source code. If you specify -qxlines , the compiler interprets the X in column 1 as a blank and treats these lines as source code.
If you do not specify -qdlines or -qxlines, the compiler handles such lines as comment lines. This is the default setting.

If you continue a debugging statement on more than one line, every continuation line must have a D in column 1 and a continuation character. If the initial line is not a debugging line, you can designate any continuation lines as debug lines provided that the statement is syntactically correct, whether or not you specify the -qdlines or -qxlines compiler option.

+----------------------------End of IBM Extension----------------------------+

Example of Fixed Source Form

C Column Numbers:
C        1         2         3         4         5         6         7
C23456789012345678901234567890123456789012345678901234567890123456789012
 
!IBM* SOURCEFORM (FIXED)
      CHARACTER ABC ; LOGICAL X          ! 2 statements on 1 line
      DO 10 I=1,10
        PRINT *,'this is the index',I  ! with an inline comment
10    CONTINUE
C
       CHARSTR="THIS IS A CONTINUED
     X CHARACTER STRING"
       ! There will be 38 blanks in the string between "CONTINUED"
       ! and "CHARACTER". You cannot have an inline comment on
       ! the initial line because it would be interpreted as part
       ! of CHARSTR (character context).
  100 PRINT *, IERROR
! The following debug lines are compiled as source lines if
! you use -qdlines
D     IF (I.EQ.IDEBUG.AND.
D    +    J.EQ.IDEBUG)     WRITE(6,*) IERROR
D     IF (I.EQ.
D    +  IDEBUG )
D    +  WRITE(6,*) INFO
       END

Free Source Form

+-------------------------------IBM Extension--------------------------------+

XL Fortran allows any line length and number of continuation lines, so long as the number of characters does not exceed 6700.

+----------------------------End of IBM Extension----------------------------+

A free source form line can specify up to 132 characters on each line, with a maximum of 39 continuation lines for a statement.

Items can begin in any column of a line, subject to the following requirements for lines and items on those lines:

A comment line is a line of white space or begins with an exclamation mark (!) that is not in a character context.
An initial line can contain any of the following items, in the following sequence:
- A statement label
- Statement text. Note that statement text is required in an initial line.
- Additional statements
- The ampersand continuation character (&).
- An inline comment
If you want to continue an initial line or continuation line in a non-character context, the continuation line must start on the first noncomment line that follows the intial line or continuation line. To define a line as a continuation line, you must place an ampersand after the statements on the previous non-comment line.
White space before and after the ampersand is optional, with the following restrictions:
- If you also place an ampersand in the first nonblank character position of the continuation line, the statement continues at the next character position following the ampersand.
- If a lexical token is continued, the ampersand must immediately follow the initial part of the token, and the remainder of the token must immediately start after the ampersand on the continuation line.
A character context can be continued if the following conditions are true:
- The last character of the continued line is an ampersand and is not followed by an inline comment. If the rightmost character of the statement text to be continued is an ampersand, a second ampersand must be entered as a continuation character.
- The first nonblank character of the next noncomment line is an ampersand.

A semicolon separates statements on a single source line, except when it appears in a character context or in a comment. Two or more separators that are on the same line and are themselves separated by only white space or other semicolons are considered to be a single separator. A separator that is the last character on a line or before an inline comment is ignored. Additional statements cannot follow a program unit END statement on the same line.

White Space

White space must not appear within lexical tokens, except in a character context or in a format specification. White space can be inserted freely between tokens to improve readability, although it must separate names, constants, and labels from adjacent keywords, names, constants, and labels.

Certain adjacent keywords may require white space. The following table lists keywords that require white space, and keywords for which white space is optional.

Table 1. Keywords Where White Space is Optional

BLOCK DATA	END FUNCTION	END SUBROUTINE
DOUBLE COMPLEX	END IF	END TYPE
DOUBLE PRECISION	END INTERFACE	END UNION
ELSE IF	END MAP	END WHERE
END BLOCK DATA	END MODULE	GO TO
END DO	END PROGRAM	IN OUT
END FILE	END SELECT	SELECT CASE
END FORALL	END STRUCTURE

See Type Declaration for details about type_spec.

Example of Free Source Form

!IBM* SOURCEFORM (FREE(F90))
!
! Column Numbers:
!        1         2         3         4         5         6         7
!23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,20
   PRINT *,'this statement&
   & is continued' ; IF (I.LT.5) PRINT *, I
 
 ENDDO
 EN&
         &D              ! A lexical token can be continued

+-------------------------------IBM Extension--------------------------------+

IBM Free Source Form

An IBM free source form line or statement is a sequence of up to 6700 characters. Items can begin in any column of a line, subject to the following requirements for lines and items on those lines:

A comment line begins with a double quotation mark (") in column 1, is a line of all white space, or is a zero-length line. A comment line must not follow a continued line. Comments can also follow an exclamation mark (!), except in a character context.
An initial line can contain any of the following items, in the following sequence:
- A statement label
- Statement text
- The minus sign continuation character (-)
- An inline comment
A continuation line immediately follows a continued line and can contain any of the following items, in the following sequence:
- Statement text
- A continuation character (-)
- An inline comment

If statement text on an initial line or continuation line is to be continued, a minus sign indicates continuation of the statement text on the next line. In a character context, if the rightmost character of the statement text to be continued is a minus sign, a second minus sign must be entered as a continuation character.

Except within a character context, white space is insignificant; that is, you can imbed white space between and within lexical tokens, without affecting the way the compiler will treat them.

Example of IBM Free Source Form

!IBM* SOURCEFORM (FREE(IBM))
"
" Column Numbers:
"        1         2         3         4         5         6         7
"23456789012345678901234567890123456789012345678901234567890123456789012
 DO I=1,10
  PRINT *,'this is -
             the index',I   ! There will be 14 blanks in the string
                            ! between "is" and "the"
 END DO
 END

+----------------------------End of IBM Extension----------------------------+

+-------------------------------IBM Extension--------------------------------+

Conditional Compilation

You can use sentinels to mark specific lines of an XL Fortran program for conditional compilation. This support allows you to port code that contains statements that are only valid or needed in an SMP environment to a non-SMP environment. You can do this by using conditional compilation lines or by using the _OPENMP C preprocessor macro.

The syntax for conditional compilation lines is as follows:

>>-cond_comp_sentinel--fortran_source_line---------------------><

cond_comp_sentinel

is a conditional compilation sentinel that is defined by the current source form and is either:

!$, C$, c$, or *$, for fixed source form; or
!$, for free source form

fortran_source_line

is an XL Fortran source line

The syntax rules for conditional compilation lines are very similar to the syntax rules for fixed source form and free source form lines. The rules are as follows:

General Rules:
A valid XL Fortran source line must follow the conditional compilation sentinel.
A conditional compilation line may contain the INCLUDE or EJECT noncomment directives.
A conditional compilation sentinel must not contain embedded white space.
A conditional compilation sentinel must not follow a source statement or directive on the same line.
If you are continuing a conditional compilation line, the conditional compilation sentinel must appear on at least one of the continuation lines or on the initial line.
You must specify the -qcclines compiler option for conditional compilation lines to be recognized. To disable recognition of conditional compilation lines, specify the -qnocclines compiler option. Specifying the -qsmp=omp compiler option enables the -qcclines option.
Trigger directives take precedence over conditional compilation sentinels. For example, if you specify the -qdirective='$' option, then lines that start with the trigger, such as !$, will be treated as comment directives, rather than conditional compilation lines.
Fixed Source Form Rules:
Conditional compilation sentinels must start in column 1.
All of the rules for fixed source form line length, case sensitivity, white space, continuation, tab formatting, and columns apply. See Fixed Source Form for information. Note that when recognition of conditional compilation lines is enabled, the conditional compilation sentinel is replaced by two white spaces.
Free Source Form Rules:
Conditional compilation sentinels may start in any column.
All of the rules for free source form line length, case sensitivity, white space, and continuation apply. See Free Source Form for information. Note that when recognition of conditional compilation lines is enabled, the conditional compilation sentinel is replaced by two white spaces.

Another way to conditionally include code, other than using conditional compilation lines, is to use the C preprocessor macro _OPENMP. This macro is defined when the C preprocessor is invoked and you specify the -qsmp=omp compiler option. See the section on passing Fortran files through the C preprocessor in the "Editing, Compiling, Linking, and Running XL Fortran Programs" chapter of the User's Guide for an example of using this macro.

Valid Example of Conditional Compilation Lines

In the following example, conditional compilation lines are used to hide OpenMP run-time routines. Code that calls OpenMP run-time routines cannot easily be compiled in a non-OpenMP environment without using conditional compilation. Since calls to the run-time routines are not directives, they cannot be hidden by the !$OMP trigger. If the code below is not compiled with the -qsmp=omp compiler option, the variable used to store the number of threads will be assigned the value of 8.

      PROGRAM PAR_MAT_MUL
      IMPLICIT NONE
      INTEGER(KIND=8)                 ::I,J,NTHREADS
      INTEGER(KIND=8),PARAMETER       ::N=60
      INTEGER(KIND=8),DIMENSION(N,N)  ::AI,BI,CI
      INTEGER(KIND=8)                 ::SUMI
!$    INTEGER OMP_GET_NUM_THREADS
 
      COMMON/DATA/ AI,BI,CI
!$OMP THREADPRIVATE (/DATA/)
 
!$OMP PARALLEL
      FORALL(I=1:N,J=1:N) AI(I,J) = (I-N/2)**2+(J+N/2)
      FORALL(I=1:N,J=1:N) BI(I,J) = 3-((I/2)+(J-N/2)**2)
!$OMP MASTER
      NTHREADS=8
!$    NTHREADS=OMP_GET_NUM_THREADS()
!$OMP END MASTER
!$OMP END PARALLEL
 
!$OMP PARALLEL DEFAULT(PRIVATE),COPYIN(AI,BI),SHARED(NTHREADS)
!$OMP DO
      DO I=1,NTHREADS
      CALL IMAT_MUL(SUMI)
      ENDDO
!$OMP END DO
!$OMP END PARALLEL
 
      END

+----------------------------End of IBM Extension----------------------------+

[ Top of Page | Previous Page | Next Page | Table of Contents | Index ]